Доброго времени суток.
Чтобы продолжить создание программы "Расходы", мне понадобится пара кнопок.
Продвинутый программер Pascal/Delphi скажет, что кнопка есть на панели Standart, есть BitBtn на панели Additional, чего еще остается желать? Отвечу. Если Вы создаете одну программу, тогда можно пользоваться стандартными компонентами, наделяя их нужными свойствами. А мне по долгу службы иногда приходилось создавать по две-три формы в день, располагая на каждой по паре кнопок: "OK" и "Cancel". Ну и что, казалось бы? Но для каждой кнопки приходилось загружать рисунок, настраивать свойства привязки (якоря), убирать надпись и т.п. Ленивому как я человеку это быстро надоедает. И тогда на ум приходит идея создания собственных компонентов кнопок, свойства которых уже установлены в таком виде, в каком они чаще всего используются.
Итак, начнем.
Прежде всего, если у Вас установлена библиотека компонентов Pro Delphi Lib, деинсталлируйте ее.
Откройте любой графический редактор и нарисуйте изображения для двух кнопок.
Обращаю Ваше внимание, что цвет левого нижнего пикселя будет считаться прозрачным!
Этот файл я назвал Set_16_16.bmp.
Второй файл я назвал Cancel_16_16.bmp
Рисунки имеют размеры 16 на 32 пикселя. Обязательно сохраните их в формате bmp. Это важно.
Фактически, можно было бы обойтись одним изображением 16 на 16, как это уже реализовано в библиотеке Pro Delphi Lib, но одним рисунком можно обходиться, если кнопки всегда доступны. Если же свойство Enabled установить в False, то на месте кнопки появится неприглядный квадратик без надписи и какого бы ни было изображения. Это не есть гуд...
Далее, при помощи блокнота создаем файл OK_Cancel_New.rc (файл OK_Cancel без New не годится, такой уже был). Обратите внимание на расширение "rc".
В этом файле пишем две строки:
OK Bitmap "Set_16_16.bmp"
CANCEL Bitmap "Cancel_16_16.bmp"
где OK и CANCEL - названия (имена, без них как обратиться к нужному?) будущих ресурсов, Bitmap - тип ресурса и далее - имена подготовленных файлов с изображениями.
Сохраните этот файл.
В папку с этим файлом и файлами рисунков скопируйте файл brcc32.exe (его можно найти в папке с делфёй ($Delphi\bin)).
Облегчим себе жизнь. Тут я и позавидую и порадуюсь одновременно за тех, кто не работал в DOS-е с командной строкой... Создадим еще один файл в той же рабочей папке с помощью того же блокнота, но, чтобы он стал исполняемым операционной системой, дадим ему расширение "bat", например: runme.bat, следующего содержания:
brcc32.exe OK_Cancel_New.rc
Эта строка запустит программу brcc32.exe, которая в качестве параметра получит ссылку на файл OK_Cancel_New.rc (еще раз подчеркиваю, что все должно быть в одной папке, чтобы не прописывать абсолютных путей и не искать потом: куда же делся результат?).
В результате очень быстрого компилирования в рабочей папке появится так необходимый нам файл
OK_Cancel_New.RES
Посмотреть его содержимое можно разными программами для работы с ресурсами, но увидите Вы примерно вот такую картину:
Открываем оболочкой Delphi файл PrDButtons.pas, содержащийся в библиотеке Pro Delphi Lib.
Внесем в него необходимые изменения:
вместо строки
{$R *.res}
запишем новую директиву компиллятору - ссылку на созданный нами файл ресурсов:
{$R OK_Cancel_New.RES}
Общие свойства, как вы можете видеть, задаются для компонента TPrDBUTTON в его конструкторе (от этого компонента наследуются новые кнопки TPrDOkButton = class( TPrDBUTTON ) и TPrDCancelButton = class( TPrDBUTTON ) ):
constructor TPrDBUTTON.Create( AOwner: TComponent );
begin
inherited Create(AOwner);
Width:=26;
Height:=26;
ControlStyle := ControlStyle - [ csSetCaption ];
ShowHint:=True;
Anchors:=[akRight]+[akBottom]; // Изменение свойств привязки к правому нижнему углу
end;
Далее - можно добавить в published разделы для кнопок свойства:
TPrDOkButton = class( TPrDBUTTON )
public
constructor Create( AOwner: TComponent ); override;
published
property Default default True;
property ModalResult default mrOK;
property NumGlyphs;
end;
TPrDCancelButton = class( TPrDBUTTON )
public
constructor Create( AOwner: TComponent ); override;
published
property Cancel default True;
property ModalResult default mrCancel;
property NumGlyphs;
end;
А в конструкторе компонентов задать значение этого свойства, равное 2, т.к. на каждую кнопку теперь полагается два рисунка:
constructor TPrDOkButton.Create( AOwner: TComponent );
begin
inherited Create(AOwner);
Default:= True;
ModalResult:= mrOK;
Hint:='Кнопка подтверждения (ОК)';
Glyph.LoadFromResourceName(HInstance, 'OK');
NumGlyphs:=2;
end;
constructor TPrDCancelButton.Create( AOwner: TComponent );
begin
inherited Create( AOwner );
Cancel := True;
ModalResult := mrCancel;
Hint:='Кнопка отмены (Cancel)';
Glyph.LoadFromResourceName(HInstance, 'CANCEL');
NumGlyphs:=2;
end;
Установите вновь библиотеку компонентов Pro Delphi Lib.
Грех - не применить модернизированные компоненты на практике. Если Вы следите за разработкой программы "Расходы", то, возможно, обратили внимание на то, что после редактирования строки нет возможности ее сохранить...
Добавьте на верхнюю панельку пару кнопок.
А дальше - по проторенной ранее дорожке: нужно добавить в список действий новую операцию:
Data_OK (внимание: свойство Caption нужно оставить пустым):
В секции частных объявлений дать декларацию новой процедуры, которую необходимо указать в обработчике onExecute новой операции:
private
{ Private declarations }
procedure SetPost();
Процедура SetPost выполнит следующие действия:
перепишет введенные в элементы управления данные в поля таблицы и выполнит сохранение данных, т.е. - отправку их в источник, затем - вернет форму к исходному виду.
procedure TMainFrm.SetPost();
begin
ADOTableMain.Edit; // Перевод таблицы в режим редактирования
ADOTableMain.FieldByName('MyDate').Value:=DataEdit.Value; // Передача значений из
ADOTableMain.FieldByName('D').Value:=DEdit.KeyValue; // элементов управления формы
ADOTableMain.FieldByName('K').Value:=KEdit.KeyValue; // в поля таблицы
ADOTableMain.FieldByName('Summa').Value:=SEdit.Value;
ADOTableMain.FieldByName('Rem').Text:=PEdit.Text;
Try
ADOTableMain.Post; // Попытка записи
Except
ADOTableMain.Cancel; // Сброс в случае ошибки
MyMessenger.TitleString:='Ошибка'; // Сообщение оператору об ошибке
MyMessenger.MessageString:='При попытке записать данные в базу возникла проблема.';
MyMessenger.Buttons:=[mbOK];
MyMessenger.ShowMessage;
end;
DBGridEh1.Enabled:=True; // Переключение грида в режим доступности
Panel3.Visible:=False; // Скрытие верней панели
end;
Не забудьте для кнопки "OK" указать Action.
Удачи.
А.В.
